***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 17, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 1SMB5930 A K 
.param
+vc0 = 4.063e-11	 vc1 = 8.412e-12	 vc2 = 1.587e-12		
+tc1 = 2.051e-2		 tc2 = 1.121e-2
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1.130e-15	   n = 1.001		  rs = 1.898e-2
+ibv = 23.4e-3		 nbv = 1.0		  bv = 16
+ikf = 4.5
***** capacitance parameter *****
+cjo = 2.662e-10	   m = 3.272e-1		  vj = 5.613e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.126		 xti = 3
+trs1 = 1.025e-3	tbv1 = 7.374e-4		tikf = -1e-3
.ends 1SMB5930
*$
